feat(ts): add php related queries

2026-04-30 16:00:39 +02:00
parent 217390cfa4
commit 84cfed05e0
11 changed files with 773 additions and 0 deletions
@@ -0,0 +1,41 @@
+((comment) @injection.content
+  (#set! injection.language "phpdoc"))
+
+(heredoc
+  (heredoc_body) @injection.content
+  (heredoc_end) @injection.language
+  (#set! injection.include-children))
+
+(nowdoc
+  (nowdoc_body) @injection.content
+  (heredoc_end) @injection.language
+  (#set! injection.include-children))
+
+; regex
+((function_call_expression
+  function: (_) @_preg_func_identifier
+  arguments: (arguments
+    .
+    (argument
+      (_
+        (string_content) @injection.content))))
+  (#set! injection.language "regex")
+  (#lua-match? @_preg_func_identifier "^preg_"))
+
+; bash
+((function_call_expression
+  function: (_) @_shell_func_identifier
+  arguments: (arguments
+    .
+    (argument
+      (_
+        (string_content) @injection.content))))
+  (#set! injection.language "bash")
+  (#any-of? @_shell_func_identifier
+    "shell_exec" "escapeshellarg" "escapeshellcmd" "exec" "passthru" "proc_open" "shell_exec"
+    "system"))
+
+(expression_statement
+  (shell_command_expression
+    (string_content) @injection.content)
+  (#set! injection.language "bash"))