[
  "{"
  "}"
] @punctuation.bracket

[
  ":"
  "-"
  "/"
] @punctuation.delimiter

"=" @operator

[
  (block_keyword)
  (lang_keyword)
] @keyword.directive

(block_name) @function

((block_name) @function.builtin
 (#any-of? @function.builtin
  "Album" "AlbumArt" "Answer" "Answerer" "Aperture" "Artist" "AskEnabled"
  "Audio" "AudioEmbed" "AudioPlayer" "Author" "Camera" "Caption" "Chat"
  "ContentSource" "CurrentPage" "Date" "DayPage" "DayPagination"
  "Description" "Even" "Excerpt" "Exif" "Exposure" "ExternalAudio"
  "FeaturedTags" "FocalLength" "Followed" "Following" "GroupMember"
  "GroupMembers" "HasAvatar" "HasFeaturedTags" "HasPages" "HasPermalink"
  "HasTags" "HideAvatar" "HideDescription" "HideFromSearchEnabled"
  "HideHeaderImage" "HideTitle" "HighRes" "HomePage" "Host" "IndexPage"
  "IsActive" "IsDeactivated" "isOriginalEntry" "JumpPage" "Label"
  "LikeCount" "Likes" "Lines" "Link" "LinkURL" "More" "NewDayDate"
  "NextDayPage" "NextPage" "NextPost" "NoLikes" "NoSearchResults"
  "NoSourceLogo" "NoteCount" "NotReblog" "Odd" "Pages" "Pagination"
  "Panorama" "PermalinkPage" "PermalinkPagination" "Photo" "Photos"
  "Photoset" "PinnedPostLabel" "PlayCount" "Post5" "PostNotes" "Posts"
  "PostSummary" "PostTitle" "PreviousDayPage" "PreviousPage"
  "PreviousPost" "Quote" "ReblogCount" "RebloggedFrom" "Reblogs"
  "RelatedPosts" "ReplyCount" "SameDayDate" "SearchPage" "ShowAvatar"
  "ShowDescription" "ShowHeaderImage" "ShowTitle" "Source" "SourceLogo"
  "Submission" "SubmissionsEnabled" "TagPage" "Tags" "Text" "Thumbnail"
  "Title" "TrackName" "Video" "VideoThumbnail" "VideoThumbnails"))

; Theme authors invent new If*/IfNot* names via <meta name="if:...">.
((block_name) @keyword.conditional
 (#match? @keyword.conditional "^[Ii]f([Nn]ot)?[A-Z]"))

(variable_name) @variable

((variable_name) @variable.builtin
 (#any-of? @variable.builtin
  "AccentColor" "Album" "AlbumArtURL" "Alt" "AmPm" "Answer" "Answerer"
  "AnswererPortraitURL" "Aperture" "Artist" "Asker" "AskerPortraitURL"
  "AskLabel" "AudioEmbed" "AudioPlayer" "Author" "AvatarShape"
  "BackgroundColor" "Beats" "BlackLogoURL" "BlogURL" "Body" "Camera"
  "CapitalAmPm" "Caption" "CopyrightYears" "CurrentPage" "CustomCSS"
  "DayOfMonth" "DayOfMonthSuffix" "DayOfMonthWithZero" "DayOfWeek"
  "DayOfWeekNumber" "DayOfYear" "Description" "EmbedUrl" "Excerpt"
  "Exposure" "ExternalAudioURL" "Favicon" "FocalLength" "FollowedName"
  "FollowedPortraitURL" "FollowedTitle" "FollowedURL" "FormattedPlayCount"
  "GroupMemberName" "GroupMemberPortraitURL" "GroupMemberTitle"
  "GroupMemberURL" "HeaderImage" "Host" "JSDescription" "JSPhotosetLayout"
  "JSPlaintextDescription" "Label" "Length" "LikeButton" "LikeCount"
  "Likes" "Line" "LinkCloseTag" "LinkOpenTag" "LinkURL" "LogoHeight"
  "LogoWidth" "MetaDescription" "Minutes" "Month" "MonthNumber"
  "MonthNumberWithZero" "Name" "NextDayPage" "NextPage" "NextPost"
  "NoteCount" "NoteCountWithLabel" "NPF" "PageNumber" "Permalink"
  "PhotoAlt" "PhotoCount" "PhotoHeight" "Photoset" "PhotosetLayout"
  "PhotoURL" "PhotoWidth" "PinnedPostLabel" "PlaintextName" "PlayCount"
  "PlayCountWithLabel" "PortraitURL" "PostAuthorName"
  "PostAuthorPortraitURL" "PostAuthorTitle" "PostAuthorURL" "PostID"
  "PostNotes" "PostNotesURL" "PostSummary" "PostTitle" "PostType"
  "PreviousDayPage" "PreviousPage" "PreviousPost" "Question" "Quote"
  "RawAudioURL" "ReblogButton" "ReblogCount" "ReblogParentName"
  "ReblogParentPortraitURL" "ReblogParentTitle" "ReblogParentURL"
  "ReblogRootName" "ReblogRootPortraitURL" "ReblogRootTitle"
  "ReblogRootURL" "RelativePermalink" "Replies" "ReplyCount" "RSS"
  "SearchQuery" "SearchResultCount" "Seconds" "ShortDayOfWeek"
  "ShortMonth" "ShortURL" "ShortYear" "Source" "SourceTitle" "SourceURL"
  "SubmitLabel" "Submitter" "SubmitterPortraitURL" "SubmitterURL" "Tag"
  "TagsAsClasses" "TagURL" "TagURLChrono" "Target" "Thumbnail" "TimeAgo"
  "Timestamp" "Title" "TitleColor" "TitleFont" "TitleFontWeight"
  "TotalPages" "TrackName" "URL" "URLEncodedPermalink"
  "URLSafeSearchQuery" "URLSafeTag" "Username" "UserNumber" "Video"
  "VideoEmbed" "VideoThumbnailURL" "WeekOfYear" "Year"))

(variable_modifier) @constant.builtin
((variable_modifier) @number
 (#match? @number "^[0-9]+(sq)?$"))

(variable_prefix) @keyword
(prefix_argument) @variable

(lang_tag) @string.special
(lang_text) @string

(attribute_name) @attribute
(attribute_value) @string